From 2ce5b370617f2877ff8c92a5f1f26a336e8c3c6a Mon Sep 17 00:00:00 2001
From: EonaCat <EonaCat@gmail.com>
Date: Sun, 26 Jul 2026 09:44:45 +0200
Subject: [PATCH] Added Windows Recall

---
 Batch/DisableRecall.bat | 26 ++++++++++++++++++++++++++
 Batch/RecallStatus.bat  | 36 ++++++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)
 create mode 100644 Batch/DisableRecall.bat
 create mode 100644 Batch/RecallStatus.bat

diff --git a/Batch/DisableRecall.bat b/Batch/DisableRecall.bat
new file mode 100644
index 0000000..90d47a8
--- /dev/null
+++ b/Batch/DisableRecall.bat
@@ -0,0 +1,26 @@
+@echo off
+:: Check administrator rights
+net session >nul 2>&1
+if %errorLevel% neq 0 (
+    echo You need to have administrator rights to execute this script!
+    echo Right click this file and choose for 'Run as admin'.
+    pause
+    exit /b
+)
+
+echo.
+echo Remove Recall via DISM
+DISM /Online /Disable-Feature /FeatureName:Recall /NoRestart
+
+echo.
+echo Add registry block for future windows updates
+:: Maak de WindowsAI-sleutel aan en zet AllowRecallEnablement op 0
+reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsAI" /v "AllowRecallEnablement" /t REG_DWORD /d 0 /f
+
+echo.
+echo Also block it for the current user
+reg add "HKEY_CURRENT_USER\SOFTWARE\Policies\Microsoft\Windows\WindowsAI" /v "AllowRecallEnablement" /t REG_DWORD /d 0 /f
+
+echo.
+echo Success! Please reboot your computer so the changes can take effect.
+pause
\ No newline at end of file
diff --git a/Batch/RecallStatus.bat b/Batch/RecallStatus.bat
new file mode 100644
index 0000000..ab140bc
--- /dev/null
+++ b/Batch/RecallStatus.bat
@@ -0,0 +1,36 @@
+@echo off
+setlocal
+
+echo Checking Windows Recall status...
+echo.
+
+REM Query the Recall optional feature
+dism /Online /Get-FeatureInfo /FeatureName:Recall > "%TEMP%\recall_status.txt" 2>&1
+
+REM Check if the feature exists
+findstr /C:"Feature name Recall is unknown" "%TEMP%\recall_status.txt" >nul
+if %ERRORLEVEL%==0 (
+    echo Windows Recall is NOT available on this system.
+    goto :cleanup
+)
+
+REM Check the feature state
+findstr /C:"State : Enabled" "%TEMP%\recall_status.txt" >nul
+if %ERRORLEVEL%==0 (
+    echo Windows Recall is ENABLED.
+    goto :cleanup
+)
+
+findstr /C:"State : Disabled" "%TEMP%\recall_status.txt" >nul
+if %ERRORLEVEL%==0 (
+    echo Windows Recall is DISABLED.
+    goto :cleanup
+)
+
+echo Unable to determine Windows Recall status.
+type "%TEMP%\recall_status.txt"
+
+:cleanup
+del "%TEMP%\recall_status.txt" >nul 2>&1
+endlocal
+pause
\ No newline at end of file